fairchat.pro

QT += qml quick core network websockets sql quickcontrols2 multimedia svg xml concurrent

SOURCES += \
    main.cpp \
    models/serverchoicemodel.cpp

HEADERS += config.h \
    models/serverchoicemodel.h

RESOURCES += qml.qrc\
            fonts.qrc\
            emojis.qrc

QMAKE_RPATHDIR += $ORIGIN/../engine/
INCLUDEPATH += $$PWD/../engine/
QMAKE_RPATHDIR += $ORIGIN
LIBS += -L../engine -lengine

win32:CONFIG(release, debug|release): PRE_TARGETDEPS += $$OUT_PWD/../engine/release/engine.lib
else:win32:CONFIG(debug, debug|release): PRE_TARGETDEPS += $$OUT_PWD/../engine/debug/engine.lib
else:unix: PRE_TARGETDEPS += $$OUT_PWD/../engine/libengine.a


TARGET = fairchat
VER_MAJ = 1
VER_MIN = 0
VER_PAT = 1
VERSION = $$sprintf("%1.%2.%3",$$VER_MAJ,$$VER_MIN,$$VER_PAT)

DEFINES += VERSION=\\\"$$VERSION\\\"

TRANSLATIONS += fairchat_de.ts

android{
    QT += androidextras
    RESOURCES += android.qrc
    DISTFILES += android/AndroidManifest.xml \
    android/gradle/wrapper/gradle-wrapper.jar \
    android/gradlew \
    android/res/values/libs.xml \
    android/build.gradle \
    android/gradle/wrapper/gradle-wrapper.properties \
    android/gradlew.bat

    QT_varfile = ""
    for(var, $$list($$find($$list($$enumerate_vars()), ^(?!QMAKE_.*|QT\..*|QT_.*|\.QMAKE.*).*$))) {
        line = $$var "$$eval($$var)"
        QT_varfile += $$join(line, "=")
    }
    write_file($$absolute_path("../android-build/VARIABLES.txt", $$OUT_PWD), QT_varfile)


    ANDROID_PACKAGE_SOURCE_DIR = $$PWD/android
    TRDESTDIR = $$system_path($$PWD/translations)
    QMAKE_POST_LINK = $$QMAKE_COPY $$shell_path($$[QT_INSTALL_TRANSLATIONS]/qt*_de.qm) $$TRDESTDIR
}

contains(ANDROID_TARGET_ARCH,armeabi-v7a) {
    ANDROID_EXTRA_LIBS = \
        $$PWD/../openssl/android-arm/libssl.so \
        $$PWD/../openssl/android-arm/libcrypto.so
}
ios{
    RESOURCES += ios.qrc

    QMAKE_INFO_PLIST = ios/Info.plist

    ios_icon.files = $$files($$PWD/ios/icons/AppIcon*.png)

    app_launch_images.files = $$PWD/ios/Launch.xib $$files($$PWD/ios/launch/LaunchImage*.png)
    QMAKE_BUNDLE_DATA += app_launch_images
    QMAKE_BUNDLE_DATA += ios_icon

    QMAKE_IOS_DEPLOYMENT_TARGET = 10
    QMAKE_IOS_TARGETED_DEVICE_FAMILY = 1
    PRODUCT_NAME = fairchat
    PRODUCT_BUNDLE_IDENTIFIER = com.osalliance.rocketchatMobile
}
winrt{
    RESOURCES += winrt.qrc

}